**Лабораторная работа 7**


**WSH как средство взаимодействия с внешними программами**

**Запуск приложений Windows**

Set WshShell = WScript.CreateObject("WScript.Shell")

WshShell.Run "notepad",3

программа Блокнот (notepad.exe) будет запущена в максимизированном (развернутом на весь экран) окне.



'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: ExecWinApp.vbs

' Язык: VBScript

' Описание: Запуск и закрытие приложение (объект WshScriptExec)

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

Dim WshShell,theNotepad,Res,Text,Title ' Объявляем переменные

' Создаем объект WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

WScript.Echo "Запускаем Блокнот"

' Запускаем приложение (создаем объект WshScriptExec)

Set theNotepad = WshShell.Exec("notepad")

WScript.Sleep 500 ' Приостанавливаем выполнение сценария

Text="Блокнот запущен (Status=" & theNotepad.Status & ")" & vbCrLf \_

& "Закрыть Блокнот?"

Title=""

' Выводим диалоговое окно на экран

Res=WshShell.Popup(Text,0,Title,vbQuestion+vbYesNo)

' Определяем, какая кнопка нажата в диалоговом окне

If Res=vbYes Then

theNotepad.Terminate ' Прерываем работу Блокнота

' Приостанавливаем выполнение сценария, для того чтобы Блокнот

' успел закрыться


WScript.Sleep 100


WScript.Echo "Блокнот закрыт (Status=" & theNotepad.Status & ")"


End If

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

Листинг 7.1. Запуск и принудительное закрытие приложения (VBScript)







**Переключение между приложениями, имитация нажатий клавиш**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: Run&ExecWinApp.vbs

' Язык: VBScript

' Описание: Запуск двух приложений и обмен данными между ними

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

Dim WshShell, theCalculator ' Объявляем переменные

' Создаем объект WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

WScript.Echo("Запускаем калькулятор и" & vbCrLf & "считаем 1+2")

' Создаем объект WshScript (запускаем Калькулятор)

Set theCalculator = WshShell.Exec("calc")

' Приостанавливаем выполнение сценария, для того чтобы

' окно Калькулятора успело появиться на экране

WScript.Sleep 500

' Активизируем окно Калькулятора

WshShell.AppActivate theCalculator.ProcessID

' Посылаем нажатия клавиш в окно Калькулятора

WshShell.SendKeys "1{+}"

WshShell.SendKeys "2"

WshShell.SendKeys "~" ' Клавиша <Enter>

WScript.Sleep 500

' Копируем результат вычисления в буфер Windows (<Ctrl>+C)

WshShell.SendKeys "^c"

' Выводим сообщение (активное окно меняется)

WScript.Echo "Закрываем калькулятор"

' Активизируем окно Калькулятора

WshShell.AppActivate theCalculator.ProcessID

' Закрываем окно Калькулятора (<Alt>+<F4>)

WshShell.SendKeys "%{F4}"

WScript.Echo "Запускаем Блокнот и копируем туда результат"

WshShell.Run "notepad" ' Запускаем Блокнот

' Приостанавливаем выполнение сценария, для того чтобы

' окно Блокнота успело появиться на экране

WScript.Sleep 1000

WshShell.AppActivate "notepad" ' Активизируем окно Блокнота

' Посылаем нажатия клавиш в окно Блокнота

WshShell.SendKeys "1{+}2="

' Вставляем содержимое буфера Windows (<Ctrl>+V)


WshShell.SendKeys "^v"


' Выводим в окно Блокнота оставшуюся информацию


WshShell.SendKeys " {(}c{)} Calculator"


'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 7.2. Запуск двух приложений и обмен данными между ними (VBScript)









**Запуск независимых консольных приложений и команд Windows**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: RunConApp.vbs

' Язык: VBScript

' Описание: Запуск независимого консольного приложения и

' определение его кода выхода

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

Dim WshShell, Code ' Объявляем переменные

' Создаем объект WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

' Запускаем утилиту xcopy с ключом "/?" и ожидаем окончания ее работы


Code=WshShell.Run("xcopy /?",1,true)

' Печатаем полученный код возврата

WScript.Echo "Код возврата: ", Code

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

Листинг 7.3. Запуск независимого консольного приложения (VBScript)



'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: RunDOSCom.vbs

' Язык: VBScript

' Описание: Выполнение внутренних команд Windows

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

Dim WshShell, Code ' Объявляем переменные

' Создаем объект WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

' Запускаем внутреннюю команду COPY


WshShell.Run "%COMSPEC% /k copy /?",1

' Запускаем внутреннюю команду DIR

WshShell.Run "%COMSPEC% /c dir %WINDIR% > windir.txt",1

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

Листинг 7.4. Запуск внутренней команды Windows (VBScript)



**Запуск дочерних консольных приложений и команд DOS, использование их входных и выходных потоков**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: ExecConApp.vbs

' Язык: VbScript

' Описание: Запуск дочернего консольного приложения

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

' Объявляем переменные

Dim ObjExec,WshShell,s,IsBreak,ArrS,ColFiles,i

' Создаем объект WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

' Запускаем команду DIR

Set ObjExec=WshShell.Exec("%COMSPEC% /c dir /b")

s=""

IsBreak=False

Do While True ' Бесконечный цикл

' Проверяем, достигнут ли конец выходного потока команды DIR

If (Not ObjExec.StdOut.AtEndOfStream) Then

' Считываем полностью выходной поток команды DIR

s=s+ObjExec.StdOut.ReadAll

End If

If IsBreak Then

Exit Do ' Выходим из цикла

End If

' Проверяем, не завершилось ли выполнение DIR

If ObjExec.Status=1 Then

IsBreak=True

Else

WScript.Sleep 100 ' Приостанавливаем сценарий на 0,1 сек

End If

Loop

ArrS=Split(s,vbCrLf) ' Формируем массив строк

ColFiles=UBound(ArrS) ' Количество файлов в текущем каталоге

WScript.StdOut.WriteLine "Всего файлов в текущем каталоге: " & ColFiles


For i=0 To ColFiles-1

WScript.StdOut.WriteLine ArrS(i) ' Выводим строки на экран

Next

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 7.5. Запуск дочернего консольного приложения (VBScript)



**Использование внешних серверов автоматизации**

**Взаимодействие с Microsoft Word**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: PrintInWord.vbs

' Язык: VBScript

' Описание: Использование из сценария внешнего объекта

' автоматизации (Microsoft Word)

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

Dim WA,WD,Sel ' Объявляем переменные

'Создаем объект¬–приложение Microsoft Word

Set WA=WScript.CreateObject("Word.Application")

' Можно было использовать конструкцию

' Set WA=CreateObject("Word.Application")

Set WD=WA.Documents.Add 'Создаем новый документ (объект Document)

WA.Visible=true ' Делаем Word видимым

Set Sel=WA.Selection 'Создаем объект Selection

Sel.Font.Size=14 'Устанавливаем размер шрифта

Sel.ParagraphFormat.Alignment=1 'Выравнивание по центру

Sel.Font.Bold=true 'Устанавливаем полужирный шрифт

Sel.TypeText "Привет!" & vbCrLf 'Печатаем строку текста

Sel.Font.Bold=false 'Отменяем полужирный шрифт

Sel.ParagraphFormat.Alignment=0 'Выравнивание по левому краю


'Печатаем строку текста

Sel.TypeText "Эти строки напечатаны с помощью WSH."

WD.PrintOut 'Выводим документ на принтер

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 7.6. Использование сервера автоматизации Microsoft Word (VBScript)



**Взаимодействие с Microsoft Excel**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: PrintInExcel.vbs

' Язык: VBScript

' Описание: Использование из сценария внешнего объекта

' автоматизации (Microsoft Excel)

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Option Explicit

Dim XL ' Объявляем переменные

'Создаем объект-приложение Microsoft Word

Set XL=WScript.CreateObject("Excel.Application")

'Делаем окно Microsoft Excel видимым

XL.Visible=true

'Открываем новую рабочую книгу

XL.WorkBooks.Add

'Устанавливаем нужную ширину колонок

XL.Columns(1).ColumnWidth = 40

XL.Columns(2).ColumnWidth = 40

XL.Columns(3).ColumnWidth = 10

'Печатаем в ячейки текст

XL.Cells(1,1).Value="Фамилия"

XL.Cells(1,2).Value="Имя"

XL.Cells(1,3).Value="Телефон"

'Выделяем три ячейки

XL.Range("A1:C1").Select

'Устанавливаем полужирный текст для выделенного диапазона

XL.Selection.Font.Bold = true

'Печатаем в ячейки текст

XL.Cells(2,1).Value="Иванов"

XL.Cells(2,2).Value="Иван"

XL.Cells(2,3).Value="555555"

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 7.7. Использование сервера автоматизации Microsoft Excel (VBScript)

